mirror of https://github.com/zxdos/zxuno.git
173 lines
5.3 KiB
NASM
173 lines
5.3 KiB
NASM
; backup.asm
|
|
;
|
|
; Copyright (C) 2019, 2021 Antonio Villena
|
|
;
|
|
; This program is free software: you can redistribute it and/or modify
|
|
; it under the terms of the GNU General Public License as published by
|
|
; the Free Software Foundation, version 3.
|
|
;
|
|
; This program is distributed in the hope that it will be useful,
|
|
; but WITHOUT ANY WARRANTY; without even the implied warranty of
|
|
; MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
|
|
; GNU General Public License for more details.
|
|
;
|
|
; You should have received a copy of the GNU General Public License
|
|
; along with this program. If not, see <https://www.gnu.org/licenses/>.
|
|
;
|
|
; SPDX-FileCopyrightText: Copyright (C) 2019, 2021 Antonio Villena
|
|
;
|
|
; SPDX-License-Identifier: GPL-3.0-only
|
|
|
|
; Compatible compilers:
|
|
; SJAsmPlus, <https://github.com/sjasmplus/sjasmplus/>
|
|
|
|
output BACKUP
|
|
|
|
include zxuno.inc
|
|
|
|
macro wreg dir, dato
|
|
call rst28
|
|
defb dir, dato
|
|
endm
|
|
|
|
org $2000 ; comienzo de la ejecución de los comandos ESXDOS
|
|
|
|
Main ld bc, zxuno_port
|
|
out (c), 0
|
|
inc b
|
|
in f, (c)
|
|
jp p, Nonlock
|
|
call Print
|
|
dz 'ROM not rooted'
|
|
ret
|
|
Nonlock ld a, scandbl_ctrl
|
|
dec b
|
|
out (c), a
|
|
inc b
|
|
in a, (c)
|
|
and $3f
|
|
ld (normal+1), a
|
|
or $c0
|
|
out (c), a
|
|
call init
|
|
ld bc, zxuno_port
|
|
ld a, scandbl_ctrl
|
|
out (c), a
|
|
inc b
|
|
normal ld a, 0
|
|
out (c), a
|
|
ret
|
|
init xor a
|
|
rst $08
|
|
db M_GETSETDRV ; A = unidad actual
|
|
jr nc, SDCard
|
|
call Print
|
|
dz 'SD card not inserted'
|
|
ret
|
|
SDCard ld b, FA_WRITE | FA_OPEN_AL ; B = modo de apertura
|
|
ld hl, FileName ; HL = Puntero al nombre del fichero (ASCIIZ)
|
|
rst $08
|
|
db F_OPEN
|
|
ld (handle+1), a
|
|
jr nc, FileFound
|
|
call Print
|
|
dz 'Can\'t open FLASH.ZX1'
|
|
ret
|
|
FileFound call Print
|
|
db 'Backing up FLASH.ZX1 to SD', 13
|
|
dz '[', 6, ' ]', 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8, 8
|
|
ld hl, $0000
|
|
Bucle push hl
|
|
ld de, $8000
|
|
ld a, $40
|
|
call rdflsh
|
|
add hl, hl
|
|
add hl, hl
|
|
ld a, h
|
|
and $0f
|
|
jr nz, punto
|
|
ld a, 'o'
|
|
rst $10
|
|
punto ld hl, $8000
|
|
ld bc, $4000
|
|
handle ld a, 0
|
|
rst $08
|
|
db F_WRITE
|
|
pop hl
|
|
jr nc, WriteOK
|
|
call Print
|
|
dz 'Write Error'
|
|
ret
|
|
WriteOK ld de, $0040
|
|
add hl, de
|
|
bit 6, h
|
|
jr z, Bucle
|
|
rst $08
|
|
db F_CLOSE
|
|
call Print
|
|
dz 13, 'Backup complete'
|
|
ret
|
|
|
|
Print pop hl
|
|
db $3e
|
|
Print1 rst $10
|
|
ld a, (hl)
|
|
inc hl
|
|
or a
|
|
jr nz, Print1
|
|
jp (hl)
|
|
|
|
; ------------------------
|
|
; Read from SPI flash
|
|
; Parameters:
|
|
; DE: destination address
|
|
; HL: source address without last byte
|
|
; A: number of pages (256 bytes) to read
|
|
; ------------------------
|
|
rdflsh ex af, af'
|
|
xor a
|
|
push hl
|
|
wreg flash_cs, 0 ; activamos spi, enviando un 0
|
|
wreg flash_spi, 3 ; envio flash_spi un 3, orden de lectura
|
|
pop hl
|
|
push hl
|
|
out (c), h
|
|
out (c), l
|
|
out (c), a
|
|
ex af, af'
|
|
ex de, hl
|
|
in f, (c)
|
|
rdfls1 ld e, $20
|
|
rdfls2 ini
|
|
inc b
|
|
ini
|
|
inc b
|
|
ini
|
|
inc b
|
|
ini
|
|
inc b
|
|
ini
|
|
inc b
|
|
ini
|
|
inc b
|
|
ini
|
|
inc b
|
|
ini
|
|
inc b
|
|
dec e
|
|
jr nz, rdfls2
|
|
dec a
|
|
jr nz, rdfls1
|
|
wreg flash_cs, 1
|
|
pop hl
|
|
ret
|
|
|
|
rst28 ld bc, zxuno_port + $100
|
|
pop hl
|
|
outi
|
|
ld b, (zxuno_port >> 8)+2
|
|
outi
|
|
jp (hl)
|
|
|
|
FileName dz 'FLASH.ZX1'
|